PerlMagick，Perl API

安裝 • 概觀 • 範例腳本 • 讀取或寫入影像 • 操作影像 • 設定影像屬性 • 取得影像屬性 • 比較影像與其重建 • 建立影像蒙太奇 • 使用 Blob • 直接存取影像像素 • 其他方法 • 處理例外• 常數

PerlMagick 是一個物件導向的 Perl 介面，用於 ImageMagick。使用此模組可以從 Perl 腳本中讀取、操作或寫入影像或影像序列。這使得它非常適合 Web CGI 腳本。您的系統上必須安裝 ImageMagick 6.5.5 或更高版本以及 Perl 5.005_02 或更高版本，才能正確建置 PerlMagick。

有許多實用的腳本可以向您展示 PerlMagick 的價值。您可以使用 MagickStudio 進行基於 Web 的影像處理和轉換，或使用 L-systems 使用數學結構建立植物影像，最後使用 WebMagick 影像導航器 瀏覽縮圖集合並選擇要查看的影像。

您可以在 ImageMagick Studio 的 Web 瀏覽器中試用 PerlMagick。或者，您可以查看 範例 以了解 PerlMagick 的選定函數。

安裝

UNIX

您的系統 RPM 儲存庫中是否有 PerlMagick？例如，在我們的 CentOS 系統上，我們按以下方式安裝 PerlMagick

yum install ImageMagick-perl

如果沒有，則必須從 ImageMagick 原始碼發行版安裝 PerlMagick。下載最新的 原始碼 版本。

使用以下命令解壓縮發行版

tar xvzf ImageMagick.tar.gz

接下來配置和編譯 ImageMagick

$ cd ImageMagick-7.1.1
$ ./configure -with-perl
$ make

如果 ImageMagick / PerlMagick 配置和編譯沒有問題，您就可以將其安裝在系統上了。安裝需要管理員權限。要安裝，請輸入

sudo make install

您可能需要配置動態鏈接器的執行時綁定

sudo ldconfig /usr/local/lib

最後，驗證 PerlMagick 安裝是否正常，請輸入

perl -MImage::Magick -le 'print Image::Magick->QuantumDepth'

恭喜，您現在擁有一個可以運作的 ImageMagick 發行版，並且可以使用 PerlMagick 轉換、合成或編輯 您的影像。

Windows XP / Windows 2000

ImageMagick 必須已安裝在您的系統上。此外，還需要 Windows 2000 的 ImageMagick 原始碼發行版。您還必須具有 Visual C++ 或 J++ 開發環境中的 nmake。將 \bin\IMagick.dll 和 \bin\X11.dll 複製到動態加載路徑中的目錄，例如 c:\perl\site\5.00502。

接下來，輸入

cd PerlMagick
perl Makefile.nt
nmake
nmake install

執行迴歸測試

要驗證安裝是否正確，請輸入

make test

在 Windows 下使用 nmake test。有一些示範腳本可用於測試 PerlMagick 可以執行的許多功能。輸入

使用 prove 工具從建置資料夾執行測試

prove --blib blib -I `pwd` -bv ./t/read.t

cd demo
make

您現在可以在 Perl 腳本中使用 PerlMagick 方法了。

概觀

任何想要使用 PerlMagick 方法的腳本都必須先在其命名空間中定義方法並實例化一個影像物件。使用以下方法完成此操作

use Image::Magick;

$image = Image::Magick->new;

PerlMagick 可以感知 量子。您可以在實例化影像物件時請求特定的量子深度

use Image::Magick::Q16;

$image = Image::Magick::Q16->new;

new() 方法採用與 SetAttribute 相同的參數。例如，

$image = Image::Magick->new(size=>'384x256');

接下來，您將學習如何讀取單張影像或影像序列、進行操作，然後顯示或寫入影像。PerlMagick 的輸入和輸出方法定義在 讀取或寫入影像 中。請參閱 設定影像屬性，了解影響影像讀取或寫入方式的方法。有關影像轉換方法的清單，請參閱 操作影像。 取得影像屬性 描述如何擷取影像的屬性。有關將影像平鋪為背景縮圖的詳細資訊，請參閱 建立影像蒙太奇。最後，有些方法不屬於上述任何類別。請查看 其他方法 以取得這些方法的清單。

當您完成 PerlMagick 物件的使用後，應該考慮將其銷毀。影像序列中的每個影像都儲存在虛擬記憶體中。這可能會佔用數百 MB 的記憶體。銷毀 PerlMagick 物件後，記憶體會釋放給其他 Perl 方法使用。建議使用 undef 來銷毀物件

undef $image;

要刪除所有影像但保留 Image::Magick 物件，請使用

@$image = ();

最後，要從多影像序列中刪除單張影像，請使用

undef $image->[$x];

下一節將說明如何使用各種 PerlMagick 方法來操作影像序列。

有些 PerlMagick 方法需要外部程式，例如 Ghostscript。這可能需要在 PATH 環境變數中明確指定路徑才能正常運作。例如（在 Linux 中），

$ENV{PATH}' . "='/../bin:/usr/bin:/usr/local/bin';

範例程式碼

以下是一個讓您入門的範例程式碼

#!/usr/local/bin/perl
use Image::Magick;

my($image, $x);

$image = Image::Magick->new;
$x = $image->Read('girl.png', 'logo.png', 'rose.png');
warn "$x" if "$x";

$x = $image->Crop(geometry=>'100x100+100+100');
warn "$x" if "$x";

$x = $image->Write('x.png');
warn "$x" if "$x";

這個程式碼會讀取三張影像、裁剪它們，並將單張影像寫入為 GIF 動畫序列。在許多情況下，您可能需要存取序列中的個別影像。以下範例說明如何執行此操作

#!/usr/local/bin/perl
use Image::Magick;

my($image, $p, $q);

$image = new Image::Magick;
$image->Read('x1.png');
$image->Read('j*.jpg');
$image->Read('k.miff[1, 5, 3]');
$image->Contrast();
for ($x = 0; $image->[$x]; $x++)
{
  $image->[$x]->Frame('100x200') if $image->[$x]->Get('magick') eq 'GIF';
  undef $image->[$x] if $image->[$x]->Get('columns') < 100;
}
$p = $image->[1];
$p->Draw(stroke=>'red', primitive=>'rectangle', points=>20,20 100,100');
$q = $p->Montage();
undef $image;
$q->Write('x.miff');

假設您想從一張 100 x 100 像素的白色畫布開始，中央有一個紅色像素。請嘗試

$image = Image::Magick->new;
$image->Set(size=>'100x100');
$image->ReadImage('canvas:white');
$image->Set('pixel[49,49]'=>'red');

在這裡，我們將 (1,1) 位置的紅色分量強度降低了一半

@pixels = $image->GetPixel(x=>1,y=>1);
$pixels[0]*=0.5;
$image->SetPixel(x=>1,y=>1,color=>\@pixels);

或者，假設您想將彩色影像轉換為灰階

$image->Quantize(colorspace=>'gray');

我們可以使用台北的 TrueType 字型為影像添加註解

$text = 'Works like magick!';
$image->Annotate(font=>'kai.ttf', pointsize=>40, fill=>'green', text=>$text);

也許您想從影像中提取所有像素強度並將其寫入 STDOUT

@pixels = $image->GetPixels(map=>'I', height=>$height, width=>$width, normalize=>true);
binmode STDOUT;
print pack('B*',join('',@pixels));

您可以使用 PerlMagick 物件執行的其他巧妙操作包括

$i = $#$p"+1";   # return the number of images associated with object p
push(@$q, @$p);  # push the images from object p onto object q
@$p = ();        # delete the images but not the object p
$p->Convolve([1, 2, 1, 2, 4, 2, 1, 2, 1]);   # 3x3 Gaussian kernel

讀取或寫入影像

使用下列方法來讀取、寫入或顯示單張影像或影像序列

讀取或寫入方法

方法	參數	傳回值	說明
讀取	一個或多個檔案名稱	讀取的影像數量	讀取單張影像或影像序列
寫入	檔案名稱	寫入的影像數量	寫入單張影像或影像序列
顯示	伺服器名稱	顯示的影像數量	將單張影像或影像序列顯示到 X 伺服器
動畫	伺服器名稱	動畫的影像數量	將影像序列製作成動畫並顯示到 X 伺服器

為了方便起見，Write()、Display() 和 Animate() 方法可以使用 SetAttribute 知道的任何參數。例如，

$image->Write(filename=>'image.png', compression=>'None');

使用 - 作為 Read() 方法的檔案名稱以從標準輸入讀取，或作為 Write() 方法的檔案名稱以寫入到標準輸出

binmode STDOUT;
$image->Write('png:-');

要從 PERL 檔案控制代碼讀取 GIF 格式的影像，請使用

$image = Image::Magick->new;
open(IMAGE, 'image.gif');
$image->Read(file=>\*IMAGE);
close(IMAGE);

要將 PNG 格式的影像寫入 PERL 檔案控制代碼，請使用

$filename = "image.png";
open(IMAGE, ">$filename");
$image->Write(file=>\*IMAGE, filename=>$filename);
close(IMAGE);

請注意，由於 ImageMagick 和 ActiveState Perl 發行版之間的 C 執行階段程式庫版本不同，或者如果其中一個 DLL 使用 /MT 選項連結，因此在 Windows 下從 Perl 檔案控制代碼讀取或寫入可能會失敗。如需說明，請參閱 跨 DLL 邊界傳遞 CRT 物件的潛在錯誤。

如果檔名中出現 %0Nd、%0No 或 %0Nx，則會將其解讀為 printf 格式規格，並以指定的場景編號的十進位、八進位或十六進位編碼替換該規格。例如：

image%03d.miff

會轉換檔案 image000.miff、image001.miff 等。

您可以選擇性地將「影像」新增至任何方法名稱。例如，ReadImage() 是方法 Read() 的別名。

處理影像

使用例如 ReadImage() 方法建立影像後，您可能會想要對其進行操作。以下列出 PerlMagick 中提供給您使用的所有影像處理方法。這裡有一些 PerlMagick 方法的範例。以下是一個呼叫影像處理方法的範例

$image->Crop(geometry=>'100x100+10+20');
$image->[$x]->Frame("100x200");

以下是您可以呼叫的其他影像處理方法列表

請注意，geometry 參數是 width 和 height 參數的簡寫（例如，geometry=>'106x80' 等同於 width=>106, height=>80）。

您可以在 Annotate() 和 Draw() 中指定 @filename。這將從磁碟上的檔案讀取文字或圖形基元指令。例如，

image->Draw(fill=>'red', primitive=>'rectangle',
 points=>'20,20 100,100  40,40 200,200  60,60 300,300');

等同於

$image->Draw(fill=>'red', primitive=>'@draw.txt');

其中 draw.txt 是磁碟上包含以下內容的檔案

rectangle 20, 20 100, 100
rectangle 40, 40 200, 200
rectangle 60, 60 300, 300

Annotate()、Comment()、Draw() 和 Label() 方法的 *text* 參數可以透過嵌入這些特殊格式字元來包含影像檔名、類型、寬度、高度或其他影像屬性

%b   file size
%c   comment
%d   directory
%e   filename extension
%f   filename
%g   page geometry
%h   height
%i   input filename
%k   number of unique colors
%l   label
%m   magick
%n   number of scenes
%o   output filename
%p   page number
%q   quantum depth
%r   image class and colorspace
%s   scene number
%t   top of filename
%u   unique temporary filename
%w   width
%x   x resolution
%y   y resolution
%z   image depth
%C   image compression type
%D   image dispose method
%H   page height
%Q   image compression quality
%T   image delay
%W   page width
%X   page x offset
%Y   page y offset
%@   bounding box
%#   signature
%%   a percent sign
\n   newline
\r   carriage return

例如，

text=>"%m:%f %wx%h"

為標題為 *bird.miff* 且寬度為 512 且高度為 480 的影像產生註解 **MIFF:bird.miff 512x480**。

您可以選擇性地在任何方法名稱中新增 *Image*。例如，TrimImage() 是方法 Trim() 的別名。

上面列出的大多數屬性在 magick 中都有類似的屬性。有關這些屬性的詳細說明，請參閱文件。

設定影像屬性

使用 Set() 方法設定影像屬性。例如，

$image->Set(dither=>'True');
$image->[$x]->Set(delay=>3);

如果此範例使用 'True' 且本文檔顯示 '{True, False}'，則您可以使用不區分大小寫的字串 'True' 和 'False'，或者您可以使用整數 1 和 0。

當您在布林屬性上呼叫 Get() 時，Image::Magick 會傳回 1 或 0，而不是字串。

以下是您可以設定的所有影像屬性清單

請注意，geometry 參數是 width 和 height 參數的簡寫（例如 geometry=>'106x80' 等同於 width=>106, height=>80）。

SetAttribute() 是方法 Set() 的別名。

上面列出的大多數屬性在 magick 中都有類似的屬性。有關這些屬性的詳細說明，請參閱文件。

取得圖片屬性

使用 Get() 方法來取得圖片屬性。例如，

($a, $b, $c) = $image->Get('colorspace', 'magick', 'adjoin');
$width = $image->[3]->Get('columns');

除了 設定圖片屬性 中列出的所有屬性之外，您還可以取得以下其他屬性

GetAttribute() 是方法 Get() 的別名。

上面列出的大多數屬性在 magick 中都有類似的屬性。有關這些屬性的詳細說明，請參閱文件。

比較影像及其重建結果

使用 Compare() 方法以數學和視覺方式標註影像及其重建結果之間的差異。該方法支援以下參數

比較參數

參數	值	說明
通道	雙精度浮點數	選擇影像通道，預設為除 Alpha 通道以外的所有通道。
fuzz	雙精度浮點數	此距離內的顏色被視為相等
影像	影像參考	影像重建結果
指標	AE、MAE、MEPP、MSE、PAE、PSNR、RMSE	使用此指標測量影像之間的差異

在此範例中，我們將 ImageMagick 標誌與銳化的重建結果進行比較

use Image::Magick;

$logo=Image::Magick->New();
$logo->Read('logo:');
$sharp=Image::Magick->New();
$sharp->Read('logo:');
$sharp->Sharpen('0x1');
$difference=$logo->Compare(image=>$sharp, metric=>'rmse');
print $difference->Get('error'), "\n";
$difference->Display();

除了報告的均方根誤差約為 0.024 之外，還會顯示差異影像，以便您直觀地識別影像之間的差異。

建立影像蒙太奇

使用 Montage() 方法建立複合影像，方法是組合多個獨立的影像。這些影像以圖塊形式排列在複合影像上，影像的名稱可選擇性地顯示在個別圖塊的正下方。例如：

$image->Montage(geometry=>'160x160', tile=>'2x2', texture=>'granite:');

以下是您可以設定的 Montage() 參數清單

請注意，geometry 參數是 width 和 height 參數的簡寫（例如 geometry=>'106x80' 等同於 width=>106, height=>80）。

MontageImage() 是方法 Montage() 的別名。

上面列出的大多數屬性在 montage 中都有對應的屬性。如需這些屬性的詳細說明，請參閱文件。

使用 Blob

Blob 包含直接表示記憶體中特定影像格式的資料，而不是磁碟上的資料。PerlMagick 支援以下任何影像 格式 的 Blob，並提供在特定影像格式之間轉換 Blob 的方法。

Blob 方法

方法	參數	傳回值	說明
ImageToBlob	任何影像 屬性	以相應影像格式表示的影像資料陣列	將影像或影像序列轉換為 Blob 陣列
BlobToImage	一個或多個 Blob	轉換為影像的 Blob 數量	將一個或多個 Blob 轉換為影像

ImageToBlob() 會以各自的格式返回影像資料。然後您可以列印、儲存到 ODBC 資料庫、寫入檔案或透過管道傳輸到顯示程式

@blobs = $image->ImageToBlob();
open(DISPLAY,"| display -") || die;
binmode DISPLAY;
print DISPLAY $blobs[0];
close DISPLAY;

方法 BlobToImage() 會返回從提供的 Blob 轉換的影像或影像序列

@blob=$db->GetImage();
$image=Image::Magick->new(magick=>'jpg');
$image->BlobToImage(@blob);

直接存取影像像素

使用這些方法可以直接存取影像像素

直接存取影像像素

方法	參數	說明
GetAuthenticPixels	geometry=>幾何, width=>整數, height=>整數, x=>整數, y=>整數	以 C 指標返回真實像素
GetVirtualPixels	geometry=>幾何, width=>整數, height=>整數, x=>整數, y=>整數	以常數 C 指標返回虛擬像素
GetAuthenticIndexQueue		以 C 指標返回色圖索引或黑色像素
GetVirtualIndexQueue		以常數 C 指標返回色圖索引或黑色像素
SyncAuthenticPixels		將真實像素同步到像素快取

其他方法

Append() 方法會附加一組影像。例如，

$p = $image->Append(stack=>{true,false});

會附加與物件 $image 相關聯的所有影像。根據預設，影像會從左到右堆疊。將 stack 設定為 True 以從上到下堆疊。

Clone() 方法會複製一組影像。例如，

$q = $p->Clone();

會將物件 $p 中的所有影像複製到 $q。您可以將此方法用於單一或多影像序列。

Coalesce() 會合成一組影像，同時遵守任何頁面偏移和處置方法。GIF、MIFF 和 MNG 動畫序列通常以影像背景開始，並且每個後續影像的大小和偏移量都不同。會返回一個新的影像序列，其中所有影像的大小都與第一個影像的虛擬畫布相同，並與序列中的下一個影像合成。例如，

$q = $p->Coalesce();

ComplexImages() 方法會對影像序列執行複雜的數學運算。例如，

$p = $image->ComplexImages('conjugate');

EvaluateImages() 方法會將算術、邏輯或關係運算式套用於一組影像。例如，

$p = $image->EvaluateImages('mean');

會平均與物件 $image 相關聯的所有影像。

Features() 方法會針對指定距離的四個方向（水平、垂直、左對角線和右對角線）中的每一個方向，返回影像中每個通道的特徵。這些特徵包括角二階矩、對比度、相關性、平方和：變異數、逆差矩、總和平均值、總和變異數、總和熵、熵、差異變異數、差異熵、相關性資訊度量 1、相關性資訊度量 2 和最大相關係數。值以 RGB、CMYK、RGBA 或 CMYKA 順序排列（取決於影像類型）。

@features = $image->Features(1);

Flatten() 方法會拼合一組影像並返回。例如，

$p = $images->Flatten(background=>'none');
$p->Write('flatten.png');

影像序列會被透過將第一個影像之後的每個影像合成到第一個影像上而建立的單一影像所取代。

Fx() 方法會將數學運算式套用於一組影像並返回結果。例如，

$p = $image->Fx(expression=>'(g+b)/2.0',channel=>'red');
$p->Write('fx.miff');

會將紅色通道替換為綠色和藍色通道的平均值。

如需此方法的詳細討論，請參閱 FX，特殊效果影像運算子。

Histogram() 會返回影像中的唯一顏色以及每種顏色的計數。返回的值是一個由紅色、綠色、藍色、不透明度和計數值組成的陣列。

Morph() 方法會對一組影像進行變形。影像像素和大小都會進行線性插值，以呈現從一個影像到下一個影像的變形外觀

$p = $image->Morph(frames=>integer);

其中 frames 是要生成的介於兩者之間的影像數量。預設值為 1。

Mosaic() 會從影像序列建立馬賽克。

方法 Mogrify() 是影像處理方法（處理影像）的單一進入點。參數是方法的名稱，後跟方法可能需要的任何參數。例如，這些呼叫是等效的

$image->Crop('340x256+0+0');
$image->Mogrify('crop', '340x256+0+0');

MogrifyRegion() 方法會將轉換套用至影像的區域。 它類似於 Mogrify()，但從區域幾何開始。 例如，假設您要增亮位於 (40, 50) 的影像 100x100 區域

$image->MogrifyRegion('100x100+40+50', 'modulate', brightness=>50);

PerceptualHash() 會將視覺上相同的影像對應至相同或相似的雜湊，這在影像擷取、驗證、索引或拷貝偵測以及數位浮水印中非常有用。 對於每個通道以及 sRGB 和 HCLp 色彩空間，會傳回 7 個雜湊值。 例如，對於 sRGB 影像，預期會有 42 個感知雜湊。

@phash = $image->PerceptualHash();

Ping() 是一種便捷方法，可以在無需將影像讀入記憶體的情況下傳回有關影像的資訊。 它會傳回影像的寬度、高度、以位元組為單位的檔案大小和檔案格式。 您可以指定多個檔案名稱，但只能指定一個檔案控制代碼

($width, $height, $size, $format) = $image->Ping('logo.png');
($width, $height, $size, $format) = $image->Ping(file=>\*IMAGE);
($width, $height, $size, $format) = $image->Ping(blob=>$blob);

這是查詢影像是否存在及其特性的更有效率且記憶體密集度較低的方式。

Poly() 會根據影像序列和對應的項（係數和次數對）建立多項式

$p = $image->Poly([0.5,1.0,0.25,2.0,1.0,1.0]);

PreviewImage() 會將指定影像的 9 個縮略圖與以不同強度套用的影像處理作業一起排列。 這可能有助於精確定位特定影像處理作業的適當參數。 從這些作業中選擇：旋轉、剪切、滾動、色調、飽和度、亮度、伽瑪、Spiff、暗淡、灰度、量化、去斑、減少雜訊、添加雜訊、銳化、模糊、閾值、邊緣偵測、擴散、太陽化、陰影、提升、分割、漩渦、內爆、波浪、油畫、炭筆畫、JPEG。 以下是一個範例

$preview = $image->Preview('Gamma');
$preview->Display();

要完全控制文字定位，您需要字體度量資訊。 使用

($x_ppem, $y_ppem, $ascender, $descender, $width, $height, $max_advance) =
  $image->QueryFontMetrics(parameters);

其中參數是 Annotate 方法的任何參數。 傳回值為

1. 字元寬度
2. 字元高度
3. 上升高度
4. 下降高度
5. 文字寬度
6. 文字高度
7. 最大水平進度
8. 邊界：x1
9. 邊界：y1
10. 邊界：x2
11. 邊界：y2
12. 原點：x
13. 原點：y

使用 QueryMultilineFontMetrics() 取得多行文字的最大文字寬度和高度。

呼叫不帶參數的 QueryColor() 以傳回已知顏色名稱的清單，或指定一個或多個顏色名稱以取得這些屬性：紅色、綠色、藍色和不透明度值。

@colors = $image->QueryColor();
($red, $green, $blue) = $image->QueryColor('cyan');
($red, $green, $blue, $alpha) = $image->QueryColor('#716baeff');

QueryColorname() 接受顏色值並傳回其各自的名稱或十六進制值；

$name = $image->QueryColorname('rgba(80,60,0,0)');

呼叫不帶參數的 QueryFont() 以傳回已知字體的清單，或指定一個或多個字體名稱以取得這些屬性：字體名稱、描述、字族、樣式、拉伸、粗細、編碼、鑄造廠、格式、度量和字形值。

@fonts = $image->QueryFont();
$weight = ($image->QueryFont('Helvetica'))[5];

呼叫不帶參數的 QueryFormat() 以傳回已知影像格式的清單，或指定一個或多個格式名稱以取得這些屬性：相鄰、Blob 支援、原始、解碼器、編碼器、描述和模組。

@formats = $image->QueryFormat();
($adjoin, $blob_support, $raw, $decoder, $encoder, $description, $module) =
  $image->QueryFormat('gif');

使用影像格式名稱呼叫 MagickToMime() 以取得其 MIME 類型，例如從 tif 取得 image/tiff。

$mime = $image->MagickToMime('tif');

使用 RemoteCommand() 將命令發送到已執行的 顯示 或 動畫 應用程式。 唯一的參數是要顯示或製作動畫的影像檔案的名稱。

$image->RemoteCommand('image.jpg');

Smush() 方法會將一組影像混合在一起。 例如，

$p = $image->Smush(stack=>{true,false},offset=>integer);

將與物件 $image 相關聯的所有影像混合在一起。 根據預設，影像會從左到右混合。 將 stack 設定為 True 以從上到下混合它們。

Statistics() 傳回影像中每個通道的影像統計資訊。 傳回值是深度、最小值、最大值、平均值、標準差、峰度、偏度和熵值的陣列，這些值以 RGB、CMYK、RGBA 或 CMYKA 順序排列（取決於影像類型）。

@statistics = $image->Statistics();

最後，Transform() 方法接受用於裁剪或調整一個或多個影像大小的完整幾何規格。 例如，

$p = $image->Transform(crop=>'100x100+0+0');

您可以選擇性地將Image添加到上面的任何方法名稱中。 例如，PingImage() 是方法 Ping() 的別名。

處理例外狀況

所有 PerlMagick 方法在成功時都會傳回未定義的字串。如果發生任何問題，錯誤將以包含內嵌數字狀態碼的字串形式傳回。狀態碼小於 400 表示警告。這表示操作未完成，但在某種程度上可以恢復。數值代碼大於或等於 400 表示錯誤，表示操作完全失敗。以下是不同方法如何傳回例外狀況

傳回數字的方法（例如 Read()、Write()）

$x = $image->Read(...);
warn "$x" if "$x";      # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number
print 0+$x;             # print the number of images read

對影像進行操作的方法（例如 Resize()、Crop()）

$x = $image->Crop(...);
warn "$x" if "$x";      # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number

應該以這種方式檢查傳回影像的方法（EvaluateSequence()、Montage()、Clone()）是否有錯誤

$x = $image->Montage(...);
warn "$x" if !ref($x);  # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number

以下是一個錯誤訊息範例

Error 400: Memory allocation failed

查看錯誤和警告代碼的完整清單。

以下說明如何使用數字狀態碼

$x = $image->Read('rose.png');
$x =~ /(\d+)/;
die "unable to continue" if ($1 == ResourceLimitError);

常數

PerlMagick 包含這些常數

BlobError
BlobWarning
CacheError
CacheWarning
CoderError
CoderWarning
ConfigureError
ConfigureWarning
CorruptImageError
CorruptImageWarning
DelegateError
DelegateWarning
DrawError
DrawWarning
ErrorException
FatalErrorException
FileOpenError
FileOpenWarning
ImageError
ImageWarning
MissingDelegateError
MissingDelegateWarning
ModuleError
ModuleWarning
Opaque
OptionError
OptionWarning
QuantumDepth
QuantumRange
RegistryError
RegistryWarning
ResourceLimitError
ResourceLimitWarning
StreamError
StreamWarning
Success
Transparent
TypeError
TypeWarning
WarningException
XServerError
XServerWarning

您可以像這樣存取它們

Image::Magick->QuantumDepth